Group {
  Air = Region[ 15 ];
  Ind1 = Region[ 12 ];
  Ind2 = Region[ 13 ];
  Ind3 = Region[ 14 ];
  Shield = Region[ 16 ];
  Surface_bn0 = Region[ 17 ];

  // Abstract regions used in the "Lib_Magnetodynamics2D_av_Cir.pro" template file
  // that is included below:
  Vol_Mag = Region[{Air, Ind1, Ind2, Ind3, Shield}]; // full magnetic domain
  Vol_C_Mag = Region[{Ind1, Ind2, Ind3}]; // massive conductors
}

Function {
  Flag_FrequencyDomain = 1;
  Freq = 50;
  mu0 = 4.e-7 * Pi;
  nu[] = 1. / mu0;
  sigma[ Vol_C_Mag ] = 5e7;
  CoefGeos[] = 1; // planar model, 1 meter thick
}

Constraint {
  { Name MagneticVectorPotential_2D;
    Case {
      { Region Surface_bn0; Value 0; }
    }
  }
  { Name Current_2D;
    Case {
      { Region Ind1; Value 400*F_Cos_wt_p[]{2*Pi*Freq, 0}; }
      { Region Ind2; Value 400*F_Cos_wt_p[]{2*Pi*Freq, 2*Pi/3}; }
      { Region Ind3; Value 400*F_Cos_wt_p[]{2*Pi*Freq, -2*Pi/3}; }
      { Region Shield; Value 0; }
    }
  }
  { Name Voltage_2D;
    Case {
    }
  }
}

Include "Lib_Magnetodynamics2D_av_Cir.pro";

PostOperation {
  { Name dyn; NameOfPostProcessing Magnetodynamics2D_av;
    Operation {
      Print[ az, OnElementsOf Vol_Mag, File "az.pos" ];
      Print[ norm_of_b, OnElementsOf Vol_Mag, File "b.pos" ];
      Print[ j, OnElementsOf Vol_Mag, File "j.pos" ];
    }
  }
}